Arduinoで遊ぶページ

Arduinoで遊んだ結果を残すページです。
garretlab
サンプルプログラム解説

概要

複数のLEDの制御順序を決めるのに配列を使います。

プログラム

定義等

/*
  Arrays

  Demonstrates the use of an array to hold pin numbers in order to iterate over
  the pins in a sequence. Lights multiple LEDs in sequence, then in reverse.

  Unlike the For Loop tutorial, where the pins have to be contiguous, here the
  pins can be in any random order.

  The circuit:
  - LEDs from pins 2 through 7 to ground

  created 2006
  by David A. Mellis
  modified 30 Aug 2011
  by Tom Igoe

  This example code is in the public domain.

  http://www.arduino.cc/en/Tutorial/Array
*/

int timer = 100;           // The higher the number, the slower the timing.
int ledPins[] = {
  2, 7, 4, 6, 5, 3
};       // an array of pin numbers to which LEDs are attached
int pinCount = 6;           // the number of pins (i.e. the length of the array)

const int型の変数timerとpinCountを定義し、初期化します。

また、int型の配列ledPins[]を定義し、初期化します。この例ように配列の要素数を記述せずに初期化することができます。

setup()

void setup() {
  // the array elements are numbered from 0 to (pinCount - 1).
  // use a for loop to initialize each pin as an output:
  for (int thisPin = 0; thisPin < pinCount; thisPin++) {
    pinMode(ledPins[thisPin], OUTPUT);
  }
}

for文を使いthisPinを0からpinCount-1(=5)まで変化させます。pinMode()でledPin[thisPin]を出力モードにします。

ledPin[]は以下のようになっているので、結果として、2、7、4、6、5、3の順に初期化されます。

thisPin ledPin[thisPin]
0 2
1 7
2 4
3 6
4 5
5 3

loop()

void loop() {
  // loop from the lowest pin to the highest:
  for (int thisPin = 0; thisPin < pinCount; thisPin++) {
    // turn the pin on:
    digitalWrite(ledPins[thisPin], HIGH);
    delay(timer);
    // turn the pin off:
    digitalWrite(ledPins[thisPin], LOW);

  }

  // loop from the highest pin to the lowest:
  for (int thisPin = pinCount - 1; thisPin >= 0; thisPin--) {
    // turn the pin on:
    digitalWrite(ledPins[thisPin], HIGH);
    delay(timer);
    // turn the pin off:
    digitalWrite(ledPins[thisPin], LOW);
  }
}

最初のfor文ではthisPinを0から5まで順に変化させ、2、7、4、6、5、3番の順でdigitalWrite()によりピンをHIGHにした後、LOWにして、1回点滅させています。delay()により点灯時間を調整しています。

2回目のfor文ではthisPinを5から0まで順に変化させ、3、5、6、4、7、2番の順でdigitalWrite()でピンを制御します。

バージョン

Arduino 1.8.5



メニューを表示するためにJavaScriptを有効にしてください。

Arduinoで遊ぶページ
Copyright © 2011 garretlab all rights reserved.
inserted by FC2 system