Arduinoで遊ぶページ

Arduinoで遊んだ結果を残すページです。
garretlab
サンプルプログラム解説

概要

基本的なHTTPサーバです。

プログラム

定義等

#include <WiFi.h>
#include <WiFiClient.h>
#include <WebServer.h>
#include <ESPmDNS.h>

const char* ssid = "........";
const char* password = "........";

WebServer server(80);

const int led = 13;

ssidとpasswordは、自分の環境に合わせて設定してください。

WebServer型の変数serverを定義します。ポート番号80で待ち受けます。

handleRoot()

void handleRoot() {
  digitalWrite(led, 1);
  server.send(200, "text/plain", "hello from esp8266!");
  digitalWrite(led, 0);
}

ルート(/)へのアクセスを扱う関数です。digitalWrite()により、LEDを点灯した後、server.send()で、クライアントにレスポンスを送信し、LEDを消灯します。

handleNotFound()

void handleNotFound() {
  digitalWrite(led, 1);
  String message = "File Not Found\n\n";
  message += "URI: ";
  message += server.uri();
  message += "\nMethod: ";
  message += (server.method() == HTTP_GET) ? "GET" : "POST";
  message += "\nArguments: ";
  message += server.args();
  message += "\n";
  for (uint8_t i = 0; i < server.args(); i++) {
    message += " " + server.argName(i) + ": " + server.arg(i) + "\n";
  }
  server.send(404, "text/plain", message);
  digitalWrite(led, 0);
}

指定されたパスが未登録の場合に実行される関数です。

server.uri()は、HTTPリクエストを受けたURIを返します。server.method()は、メソッドを返します。

server.args()は、HTTPリクエストパラメータ数を返します。server.argName()は、リクエストパラメータの名前を返します。server.arg()は、リクエストパラメータの値を返します。

最後に、server.send()で、クライアントにレスポンスを送信します。

setup()

void setup(void) {
  pinMode(led, OUTPUT);
  digitalWrite(led, 0);
  Serial.begin(115200);
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  Serial.println("");

  // Wait for connection
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("Connected to ");
  Serial.println(ssid);
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  if (MDNS.begin("esp32")) {
    Serial.println("MDNS responder started");
  }

  server.on("/", handleRoot);

  server.on("/inline", []() {
    server.send(200, "text/plain", "this works as well");
  });

  server.onNotFound(handleNotFound);

  server.begin();
  Serial.println("HTTP server started");
}

WiFi.mode()は、WiFiの動作モードを設定します。ここでは、ステーションモードに設定しています。WiFiは、WiFi.cppで定義されている変数です。

この例では、明に動作モードを設定していますが、他の例では設定していないものも多く見受けられます。ソースコードを読んでみると、WiFi.begin()の中で、ステーションモードに設定しているようです。なので、設定する必要はないと思います。

WiFi.begin()により、ssidで指定したアクセスポイントに接続します。この際のパスフレーズは、passwordです。

WiFi.status()は、現在の接続状態を返却します。アクセスポイントに接続しているときは、WL_CONNECTEDが返ってきます。

WiFi.localIP()は、現在割り当てられているIPアドレスを返却します。

MDNS.begin()は、mDNS(マルチキャストDNS) にホスト名を登録します。MDNSは、ESPmDNS.cppで定義されています。これにより、esp32.localという名前で、ホスト名が解決できると思うのですが、私の環境ではうまく動作しませんでした。

server.on()で、指定したURIにアクセスがあった時に呼び出す関数を登録します。2つ目のserver.on()では、ラムダ式を登録しています。

server.onNotFound()は、登録していないURIにアクセスがあった時に呼び出す関数を登録します。

最後に、server.begin()で、HTTPサーバを開始します。

loop()

void loop(void) {
  server.handleClient();
}

server.handleClient()で、登録した情報に従ってクライアントからのリクエストを処理します。

バージョン

1.0.0



メニューを表示するためにJavaScriptを有効にしてください。

Arduinoで遊ぶページ
Copyright © 2018 garretlab all rights reserved.
inserted by FC2 system