はじめに 基本的なHTTPサーバです。
プログラム 定義等
1
2
3
4
5
6
7
8
9
10
11
12
#include <WiFi.h>
#include <WiFiClient.h>
#include <WebServer.h>
#include <ESPmDNS.h>
const char * ssid = "........" ;
const char * password = "........" ;
WebServer server ( 80 );
const int led = 13 ;
ssidとpasswordは、自分の環境に合わせて設定してください。
WebServer型 の変数serverを定義します。ポート番号80で待ち受けます。
handleRoot()
13
14
15
16
17
18
void handleRoot () {
digitalWrite ( led , 1 );
server . send ( 200 , "text/plain" , "hello from esp32!" );
digitalWrite ( led , 0 );
}
ルート(/)へのアクセスを扱う関数です。digitalWrite() により、LEDを点灯した後、server.send() で、クライアントにレスポンスを送信し、LEDを消灯します。
handleNotFound()
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
void handleNotFound () {
digitalWrite ( led , 1 );
String message = "File Not Found \n\n " ;
message += "URI: " ;
message += server . uri ();
message += " \n Method: " ;
message += ( server . method () == HTTP_GET ) ? "GET" : "POST" ;
message += " \n Arguments: " ;
message += server . args ();
message += " \n " ;
for ( uint8_t i = 0 ; i < server . args (); i ++ ) {
message += " " + server . argName ( i ) + ": " + server . arg ( i ) + " \n " ;
}
server . send ( 404 , "text/plain" , message );
digitalWrite ( led , 0 );
}
指定されたパスが未登録の場合に実行する関数です。
server.uri() は、HTTPリクエストを受けたURIを返します。server.method() は、メソッドを返します。
server.args() は、HTTPリクエストパラメータ数を返します。server.argName() は、リクエストパラメータの名前を返します。server.arg() は、リクエストパラメータの値を返します。
最後に、server.send() で、クライアントにレスポンスを送信します。
setup()
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
void setup ( void ) {
pinMode ( led , OUTPUT );
digitalWrite ( led , 0 );
Serial . begin ( 115200 );
WiFi . mode ( WIFI_STA );
WiFi . begin ( ssid , password );
Serial . println ( "" );
// Wait for connection
while ( WiFi . status () != WL_CONNECTED ) {
delay ( 500 );
Serial . print ( "." );
}
Serial . println ( "" );
Serial . print ( "Connected to " );
Serial . println ( ssid );
Serial . print ( "IP address: " );
Serial . println ( WiFi . localIP ());
if ( MDNS . begin ( "esp32" )) {
Serial . println ( "MDNS responder started" );
}
server . on ( "/" , handleRoot );
server . on ( "/inline" , []() {
server . send ( 200 , "text/plain" , "this works as well" );
});
server . onNotFound ( handleNotFound );
server . begin ();
Serial . println ( "HTTP server started" );
}
WiFi.mode() は、WiFiの動作モードを設定します。ここでは、ステーションモードに設定しています。WiFiは、WiFi.cppで事前定義されている変数です(利用者が定義する必要はありません)。
この例では、明示的にに動作モードを設定していますが、他の例では設定していないものも多く見受けられます。ソースコードを読んでみると、WiFi.begin() の中で、ステーションモードに設定しているようです。なので、設定する必要はないと思います。
WiFi.begin() により、ssidで指定したアクセスポイントに接続します。この際のパスフレーズは、passwordです。
WiFi.status() は、現在の接続状態を返却します。アクセスポイントに接続しているときは、WL_CONNECTEDが返ってきます。
WiFi.localIP() は、現在割り当てられているIPアドレスを返却します。
MDNS.begin() は、mDNS(マルチキャストDNS) にホスト名を登録します。MDNSは、ESPmDNS.cppで定義されています(利用者が定義する必要はありません)。これにより、esp32.localという名前で、ホスト名が解決できるようになります。
server.on() で、指定したURIにアクセスがあった時に呼び出す関数を登録します。59行目は、"/" へのアクセス時の関数を登録します。61行目は、"/inline" へのアクセスする関数を、ラムダ式として登録しています。
server.onNotFound() は、登録していないURIにアクセスがあった時に呼び出す関数を登録します。
最後に、server.begin() で、HTTPサーバを開始します。
loop()
71
72
73
void loop ( void ) {
server . handleClient ();
}
server.handleClient() で、登録した情報に従ってクライアントからのリクエストを処理します。
バージョン
Hardware: ESP-WROOM-32 Software: Arduino core for the ESP32 2.0.4
最終更新日
September 4, 2022