Arduinoで遊ぶページ
Arduinoで遊んだ結果を残すページです
p11_CrystalBall

はじめに

キャラクタ液晶ディスプレイを制御します。

プログラム

定義等

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
/*
  Arduino Starter Kit example
  Project 11 - Crystal Ball

  This sketch is written to accompany Project 11 in the Arduino Starter Kit

  Parts required:
  - 220 ohm resistor
  - 10 kilohm resistor
  - 10 kilohm potentiometer
  - 16x2 LCD screen
  - tilt switch

  created 13 Sep 2012
  by Scott Fitzgerald

  http://www.arduino.cc/starterKit

  This example code is part of the public domain.
*/

// include the library code:
#include <LiquidCrystal.h>

// initialize the library with the numbers of the interface pins
LiquidCrystal lcd(12, 11, 5, 4, 3, 2);

// set up a constant for the tilt switch pin
const int switchPin = 6;

// variable to hold the value of the switch pin
int switchState = 0;

// variable to hold previous value of the switch pin
int prevSwitchState = 0;

// a variable to choose which reply from the crystal ball
int reply;
 

キャラクタ液晶ディスプレイ(LCD)を制御するためのLiquidCrystalライブラリを利用するため、LiquidCrystal.hをインクルードしています。その後、LiquidCrystal型の変数lcdを定義します。

その後、変数を定義しています。

setup()

40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
void setup() {
  // set up the number of columns and rows on the LCD
  lcd.begin(16, 2);

  // set up the switch pin as an input
  pinMode(switchPin, INPUT);

  // Print a message to the LCD.
  lcd.print("Ask the");
  // set the cursor to column 0, line 1
  // line 1 is the second row, since counting begins with 0
  lcd.setCursor(0, 1);
  // print to the second line
  lcd.print("Crystal Ball!");
}
 

lcd.begin(16, 2)でLCDを初期化します。横16文字、縦2文字のLCDを使っています。

pinMode()を使い、switchPinを入力モードにします。

lcd.print()はLCDに文字を表示する関数、lcd.setCursor()は、LCD上のカーソル位置を設定する関数です。

loop()

 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
void loop() {
  // check the status of the switch
  switchState = digitalRead(switchPin);

  // compare the switchState to its previous state
  if (switchState != prevSwitchState) {
    // if the state has changed from HIGH to LOW you know that the ball has been
    // tilted from one direction to the other
    if (switchState == LOW) {
      // randomly chose a reply
      reply = random(8);
      // clean up the screen before printing a new reply
      lcd.clear();
      // set the cursor to column 0, line 0
      lcd.setCursor(0, 0);
      // print some text
      lcd.print("the ball says:");
      // move the cursor to the second line
      lcd.setCursor(0, 1);

      // choose a saying to print based on the value in reply
      switch (reply) {
        case 0:
          lcd.print("Yes");
          break;

        case 1:
          lcd.print("Most likely");
          break;

        case 2:
          lcd.print("Certainly");
          break;

        case 3:
          lcd.print("Outlook good");
          break;

        case 4:
          lcd.print("Unsure");
          break;

        case 5:
          lcd.print("Ask again");
          break;

        case 6:
          lcd.print("Doubtful");
          break;

        case 7:
          lcd.print("No");
          break;
      }
    }
  }
  // save the current switch state as the last state
  prevSwitchState = switchState;
}

digitalRead()を使ってSwitchPinの値をswitchStateに代入します。

switchStateとpreviousSwitchStateの値が異なれば、スイッチの状態が変わったということなので、switchStateの状態を調べて、LOWであれば(ボタンが押されていれば)、以下の処理を行います。

random()は、乱数を返す関数です。ここでは、0から7までの数字を生成しています。

lcd.clear()は、LCDに表示されている文字を消す関数です。

lcd.setCursor()でカーソル位置を設定し、lcd.print()で文字を表示します。

最後に、switchStateをpreviousSwitchStateに保存します。

バージョン

Hardware:Arduino Uno
Software:Arduino 1.8.13

最終更新日

June 19, 2020

inserted by FC2 system