barGraph

はじめに

アナログセンサから読み取った値に応じて、10個のLEDを光らせます。

アナログの0番ピンにセンサが、デジタルピンの2番ピンから11番ピンにLEDが接続されている想定です。

プログラム

定義等 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

/*
  LED bar graph

  Turns on a series of LEDs based on the value of an analog sensor.
  This is a simple way to make a bar graph display. Though this graph uses 10
  LEDs, you can use any number by changing the LED count and the pins in the
  array.

  This method can be used to control any series of digital outputs that depends
  on an analog input.

  The circuit:
  - LEDs from pins 2 through 11 to ground

  created 4 Sep 2010
  by Tom Igoe

  This example code is in the public domain.

  https://www.arduino.cc/en/Tutorial/BuiltInExamples/BarGraph
*/

// these constants won't change:
const int analogPin = A0;   // the pin that the potentiometer is attached to
const int ledCount = 10;    // the number of LEDs in the bar graph

int ledPins[] = {
  2, 3, 4, 5, 6, 7, 8, 9, 10, 11
};   // an array of pin numbers to which LEDs are attached

const int型の変数analogPinとledCountを定義し初期化します。

int型の配列ledPinsを定義し初期化します。

setup() 

32
33
34
35
36
37
38

void setup() {
  // loop over the pin array and set them all to output:
  for (int thisLed = 0; thisLed < ledCount; thisLed++) {
    pinMode(ledPins[thisLed], OUTPUT);
  }
}

for文を使って、thisLedを0から9まで変化させ、デジタルのledPins[thisLed]番ピンをpinMode()を使い、出力モードにします。結果として、デジタルピンの2番から11番までが出力モードになります。

loop() 

39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

void loop() {
  // read the potentiometer:
  int sensorReading = analogRead(analogPin);
  // map the result to a range from 0 to the number of LEDs:
  int ledLevel = map(sensorReading, 0, 1023, 0, ledCount);

  // loop over the LED array:
  for (int thisLed = 0; thisLed < ledCount; thisLed++) {
    // if the array element's index is less than ledLevel,
    // turn the pin for this element on:
    if (thisLed < ledLevel) {
      digitalWrite(ledPins[thisLed], HIGH);
    }
    // turn off all pins higher than the ledLevel:
    else {
      digitalWrite(ledPins[thisLed], LOW);
    }
  }
}

analogRead()を使い読み取った値をsensorReadingに代入します。analogRead()が出力する値は0から1023までです。map()を使い、その値を0からledCount(=10)に変換し、ledLevelに代入します。この時点で、ledLevelには光らせるLEDの数が代入されています。

for文を使って、thisLedを0から9まで変化させます。if文を使いthisLedとledLevelとを比較します。thisLedがledLevelより小さいときは、digitalWrite()を使い、ledPins[thisLed]をHIGHにしledPins[thisLed]に接続されているLEDを点灯させます。そうでなければ(else)、ledPins[thisLed]に接続されているLEDを消灯します。

バージョン

Hardware:Arduino Uno
Software:Arduino 1.8.16

最終更新日

September 11, 2021

inserted by FC2 system