ExternalWakeUp

はじめに

外部(デジタルピン)からの入力によって、ディープスリープ状態から復帰します。ESP-IDFの機能を利用しています。

プログラム

定義等

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
/*
Deep Sleep with External Wake Up
=====================================
This code displays how to use deep sleep with
an external trigger as a wake up source and how
to store data in RTC memory to use it over reboots

This code is under Public Domain License.

Hardware Connections
======================
Push Button to GPIO 33 pulled down with a 10K Ohm
resistor

NOTE:
======
Only RTC IO can be used as a source for external wake
source. They are pins: 0,2,4,12-15,25-27,32-39.

Author:
Pranav Cherukupalli <cherukupallip@gmail.com>
*/

#define BUTTON_PIN_BITMASK 0x200000000 // 2^33 in hex

RTC_DATA_ATTR int bootCount = 0;
 

BUTTON_PIN_BITMASKは定義していますが、このスケッチでは利用していません(コメントアウトされています)。

bootCountは、何回ブートされたかをカウントする変数です。RTC_DATA_ATTRは、変数をRTC SLOW Memoryに配置するよう指示します。RTC SLOW Memoryはディープスリープ中でもデータが消えないメモリです。

28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
/*
Method to print the reason by which ESP32
has been awaken from sleep
*/
void print_wakeup_reason(){
  esp_sleep_wakeup_cause_t wakeup_reason;

  wakeup_reason = esp_sleep_get_wakeup_cause();

  switch(wakeup_reason)
  {
    case ESP_SLEEP_WAKEUP_EXT0 : Serial.println("Wakeup caused by external signal using RTC_IO"); break;
    case ESP_SLEEP_WAKEUP_EXT1 : Serial.println("Wakeup caused by external signal using RTC_CNTL"); break;
    case ESP_SLEEP_WAKEUP_TIMER : Serial.println("Wakeup caused by timer"); break;
    case ESP_SLEEP_WAKEUP_TOUCHPAD : Serial.println("Wakeup caused by touchpad"); break;
    case ESP_SLEEP_WAKEUP_ULP : Serial.println("Wakeup caused by ULP program"); break;
    default : Serial.printf("Wakeup was not caused by deep sleep: %d\n",wakeup_reason); break;
  }
}
 

print_wakeup_reason()は、ディープスリープからの復帰理由を表示します。

esp_sleep_get_wakeup_cause()は、ディープスリープから復帰した理由を返すESP-IDFのAPIです。

setup()

48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
void setup(){
  Serial.begin(115200);
  delay(1000); //Take some time to open up the Serial Monitor

  //Increment boot number and print it every reboot
  ++bootCount;
  Serial.println("Boot number: " + String(bootCount));

  //Print the wakeup reason for ESP32
  print_wakeup_reason();

  /*
  First we configure the wake up source
  We set our ESP32 to wake up for an external trigger.
  There are two types for ESP32, ext0 and ext1 .
  ext0 uses RTC_IO to wakeup thus requires RTC peripherals
  to be on while ext1 uses RTC Controller so doesnt need
  peripherals to be powered on.
  Note that using internal pullups/pulldowns also requires
  RTC peripherals to be turned on.
  */
  esp_sleep_enable_ext0_wakeup(GPIO_NUM_33,1); //1 = High, 0 = Low

  //If you were to use ext1, you would use it like
  //esp_sleep_enable_ext1_wakeup(BUTTON_PIN_BITMASK,ESP_EXT1_WAKEUP_ANY_HIGH);

  //Go to sleep now
  Serial.println("Going to sleep now");
  esp_deep_sleep_start();
  Serial.println("This will never be printed");
}
 

最初にbootCountをインクリメントすることで、ブート回数を設定した後、print_wakeup_reason()でブート理由を表示します。

esp_sleep_enable_ext0_wakeup()は、デジタルピンを使ったディープスリープからの復帰を有効にする関数です。今回は、GPIO33が1(=HIGH)になったら復帰するように設定しています。

次に、esp_deep_sleep_start()で、実際にディープスリープします。

loop()

80
81
82
void loop(){
  //This is not going to be called
}

何もしません。

実行結果

以下に実行結果を示します。

初回のブートは、Wakeup was not caused by deep sleep と表示され、2回目のブート(ディープスリープからの復帰)は、Wakeup caused by external signal using RTC_IOと表示されました。

バージョン

Hardware:ESP-WROOM-32
Software:Arduino core for the ESP32 2.0.4

最終更新日

September 4, 2022

inserted by FC2 system